#!ipxe

cpuid --ext 29 && set arch amd64 || set arch i386

set root http://boot.xargon.de
colour --rgb 0xffffff 7
console --x 1280 --y 960 --picture ${root}/boot.png --left 120 --right 120 --top 200 --bottom 200 || goto begin

:begin

menu ${net0/mac} / ${net0/ip} (${platform})
item --gap -- -- System installation --
item debian               Install Debian stable
item arch                 Install Archlinux
item win10                Install Windows 10
item --gap -- -- Live --
item grml-${platform}     Start grml-small 2020.06
item debian-live          Start Debian Live XFCE
item winpe                Start Windows PE
item gparted              Start gparted
item memtest              Start Memtest86+ V5
item --gap
item shell                Shell
choose selected
goto ${selected}

:win10
sanboot --no-describe --drive 0x81 ${root}/win10_iot_64.iso || goto begin

:winpe
kernel winpe/wimboot
initrd winpe/${arch}/media/Boot/BCD                     BCD
initrd winpe/${arch}/media/Boot/boot.sdi                boot.sdi
initrd winpe/${arch}/media/sources/boot.wim             boot.wim
boot || goto begin

:debian
set base-path http://ftp.debian.org/debian/dists/stable/main/installer-${arch}/current/images/netboot/debian-installer/${arch}

imgfetch ${base-path}/initrd.gz
imgload ${base-path}/linux debian-installer/locale=en_US.UTF-8 debian-installer/language=en debian-installer/country=DE keyboard-configuration/xkb-keymap=de netcfg/choose_interface=${net0/mac}

prompt
imgexec || goto begin

:arch
boot http://boot.xargon.de/arch/ipxe-arch.5ee66f360339.pxe || goto begin

:debian-live
initrd ${root}/debian/${arch}/initrd.img
chain ${root}/debian/${arch}/vmlinuz boot=live fetch=${root}/debian/${arch}/filesystem.squashfs || goto begin

:grml-pcbios
imgfetch ${root}/grml/${arch}/initrd.img
imgload ${root}/grml/${arch}/vmlinuz boot=live fetch=${root}/grml/${arch}/grml-small.squashfs apm=power-off nomce noprompt noeject grml2ram vga=791 lang=de ssh=grml
imgexec || goto begin

:grml-efi
linuxefi http://boot.xargon.de/grml/${arch}/vmlinuz boot=live fetch=http://boot.xargon.de/grml/${arch}/grml-small.squashfs apm=power-off nomce noprompt noeject grml2ram vga=791 lang=de ssh=grml
initrdefi http://boot.xargon.de/grml/${arch}/initrd.img
#imgexec || goto begin

:gparted
initrd ${root}/gparted/${arch}/initrd.img
chain ${root}/gparted/${arch}/vmlinuz boot=live fetch=${root}/gparted/${arch}/filesystem.squashfs || goto begin

:memtest
boot ${root}/memtest/memtest86.bin || goto begin

:shell
shell
goto begin